This is a very short digression: I found Prof. Matt Strassler’s blog very intriguing. Here are a couple of links:
Strassler – Fields and their particles (with math)
Strassler – How the Higgs field works (with math)
It attemps (and imho succeds at ) an introduction to the basic concepts of the Standard Model and the mechanism by which particles acquire mass through the Higgs field. It’s presented in a very intuitive way, while preserving enough of the mathematical structure. All the math is actually pretty elementary and there are some white lies here and there, which I think is a good thing. When you’re introducing someone to a subject, you want to sweep the dust under the carpet at first.
All in all, this much quality in science popularization is very rare I think.
I fed one of the naive models of field-particle interactions in the posts above into Mathematica’s NDSolve routine. The model (a system of PDEs) describes the interaction of two massless fields with a massive particle-field: when two quanta of the fields bump into each other, a particle is created as a vibration in the particle-field. The system is the following set of wave equations with additional cross terms that account for the interaction
![\displaystyle \begin{cases} \frac{\partial^2}{{\partial t}^2}A - c^2\frac{\partial^2}{{\partial x}^2}A = \gamma B Z \\ \frac{\partial^2}{{\partial t}^2}B - c^2\frac{\partial^2}{{\partial x}^2}B = \gamma A Z \\ \frac{\partial^2}{{\partial t}^2}Z - c^2\frac{\partial^2}{{\partial x}^2}Z = - 4\pi^2 \nu^2 Z + \gamma A B \end{cases} \ \ \ \ \](https://s0.wp.com/latex.php?latex=%5Cdisplaystyle+%5Cbegin%7Bcases%7D+%5Cfrac%7B%5Cpartial%5E2%7D%7B%7B%5Cpartial+t%7D%5E2%7DA+-+c%5E2%5Cfrac%7B%5Cpartial%5E2%7D%7B%7B%5Cpartial+x%7D%5E2%7DA+%3D+%5Cgamma+B+Z+%5C%5C+%5Cfrac%7B%5Cpartial%5E2%7D%7B%7B%5Cpartial+t%7D%5E2%7DB+-+c%5E2%5Cfrac%7B%5Cpartial%5E2%7D%7B%7B%5Cpartial+x%7D%5E2%7DB+%3D+%5Cgamma+A+Z+%5C%5C+%5Cfrac%7B%5Cpartial%5E2%7D%7B%7B%5Cpartial+t%7D%5E2%7DZ+-+c%5E2%5Cfrac%7B%5Cpartial%5E2%7D%7B%7B%5Cpartial+x%7D%5E2%7DZ+%3D+-+4%5Cpi%5E2+%5Cnu%5E2+Z+%2B+%5Cgamma+A+B+%5Cend%7Bcases%7D+%5C+%5C+%5C+%5C+%5C+&bg=ffffff&fg=000000&s=2 "\displaystyle \begin{cases} \frac{\partial^2}{{\partial t}^2}A - c^2\frac{\partial^2}{{\partial x}^2}A = \gamma B Z \\ \frac{\partial^2}{{\partial t}^2}B - c^2\frac{\partial^2}{{\partial x}^2}B = \gamma A Z \\ \frac{\partial^2}{{\partial t}^2}Z - c^2\frac{\partial^2}{{\partial x}^2}Z = - 4\pi^2 \nu^2 Z + \gamma A B \end{cases} \ \ \ \ \")
As initial conditions we choose 
Here is an animation depicting what happens
It can be interpreted as the creation of a particle (the blue graph).
For those of you that are curious and want to fiddle with the code, I’ve included it here:
\[Gamma] = 0.85; (* interaction parameter *)
m = 2; (* (mass of the particle) x c^2 / (h bar) *)
\[Nu] = 1; (* frequency *)
\[Mu] = 1; (* wavenumber *)
G[z_] := Exp[-z^2] Cos[2 \[Pi] z]; (* wavepacket definition *)
Sol1 = NDSolve[{ (* NDSolve routine *)
{ (* system of PDEs above *)
D[Z[t, x], t,t] - (\[Nu]/\[Mu])^2 D[Z[t, x], x, x] == -4 \[Pi]^2 m^2 Z[t,x] + \[Gamma] A[t, x]*B[t, x],
D[A[t, x], t,t] - (\[Nu]/\[Mu])^2 D[A[t, x], x, x] == \[Gamma] B[t, x]*Z[t, x],
D[B[t, x], t,t] - (\[Nu]/\[Mu])^2 D[B[t, x], x, x] == \[Gamma] A[t, x]*Z[t, x]
},
Z[0, x] == 0, Derivative[1, 0][Z][0, x] == 0, (* initial values *)
A[0, x] == N[G[-\[Mu] (x + 4)]], Derivative[1, 0][A][0, x] == D[G[\[Nu] s - \[Mu] (x + 4)], s] /. s -> 0,
B[0, x] == N[G[\[Mu] (x - 4)]], Derivative[1, 0][B][0, x] == D[G[\[Nu] s + \[Mu] (x - 4)], s] /. s -> 0},
(* initial values of A,B are wavepackets traveling in opposite directions *)
{Z, A, B}, (* variables *)
{t, 0, 20}, {x, -20, 20} (* range *)
];
Animate[
Plot[
Evaluate[{20*Z[t, x], A[t, x], B[t, x]} /. Sol1],
{x, -8, 8},
PlotRange -> {{-8, 8}, {-1.5, 1.5}},
PlotPoints -> 50],
{t, 0, 12 },
AnimationRate -> 1
]
